мой макросик, юзаю в энтранс ту тэмпл фернон, лвл40 свордом.
Разрешение у меня 1024х768, играю в оконном режиме.
Мои хоткеи: 1,2,3 - скилы атаки
q - снэки
e - шоколадка, оч хорошо пополняет ману.
6 - баф "капля"
4 - баф "плюсик"
Что мак делает:
бродит туда сюда по фернону и бьет всех подряд, если спадает капля - бафает ее(немного бажный момент, но не стоящий внимания), если вокруг нет врагов в течении 2 секунд(или гдето так) - бежит в другую точку предварительно бафнув плюсик. Подбирает всё(если пытается подобрать чужое - начинает палвено дергаться...). Точки всего 2 - правый верхний и нижний углы(мне так нравится). Под другие локи можете поковырять координаты, я там закоментил место в котором они.
В олбщем пользуйтесь, критикуйте, дорабатывайте и выкладывайте сюда)
Code
SetActivewindow Nostale //если у вас другое название окна - поменяйте на него
Delay 500
constants
eattimer=0
notarget=0
manatimer=0
x=0
y=0
end
Delay 500
loop 5000 //можно больше.
isblack 116,60 //если хп меньше 10% - вы скорее всего мертвы. Остановить скрипт в этом случае.
SetActivewindow AC Tool 5.4.0 - E:\Program Files\AC Tool\nosbasic.mac //заменить на ваше название окна АЦ тулза
delay 500
mousepos 750,600 //ф2 на стоп у меня не работает так что просто кликаю в точку где кнопка стоп.
leftclick
end
isred 66,111 //проверяем капельку. Бажный момент в том, что в ферноне цвет земли в основном тоже красный, так что капля кастуется только когда ее самой нет а чар токачто скастовал плюсик.
else
keys 6 //кастуем капельку.
delay 3000 //ждем пока скастуется.
end
keys {SPACE} 123 //выбираем цель и бьем ее 3мя скилами. Сначала будет срабатывать 3, потом 2, потом 1 - в зависимости от того прошла ли задержка на них или нет. Если у всех 3 задержка - бьем обычной атакой.
keys x //подбираем 5 раз. ХЗ почему 5 - мне так нравится.
delay 100
keys x
delay 100
keys x
delay 100
keys x
delay 100
keys x
delay 100
keys x
isblack 490,40 //проверяем есть ли у нас в данный момент выбранная цель.
setconst notarget=0
keys {ESC} //закрываем окошко с целью. Это надо на тот случай, если мы пробелом навелись на врага, стоящего далеко за стеной. Без этой строчки бот зависает и тычится в стену в этом случае.
end
compute notarget=$notarget+1
if $notarget>4 //если уже 4 раза проверка показала что цели нет - топаем в другую точку.
//compute x=875+INT(rnd(135)) //случайные координаты на миникарте
//compute y=65+INT(rnd(135))
compute y=70+int(117*int(rnd(2))) //либо y=70 либо 187, т.е. курсируем между двумя углами.
keys 4 //надеваем плюсик
delay 3000 //ждем пока скастуется.
//mousepos $x,$y //это если у нас и Х и У задаются переменными.
mousepos 1002,$y
leftclick
setconst notarget=0
end
compute eattimer=$eattimer+1
compute manatimer=$manatimer+1
isblack 210, 61 //если нас покоцали - жрем, но не слишком часто чтобы не подавиться.
if $eattimer>4
keys q
setconst eattimer=0
end
end
isblack 140, 81 //если маны совсем уж мало - кушаем шоколадку.
if $manatimer>4
keys e
setconst manatimer=0
end
end
end
ЗЫ лучший способ почитать скрипт - закинуть его сразу в АЦ тулз ибо там всё подсвечено цветами.
ЗЫЫ А вот еще моя програмка для определения координат курсора и цвета в его точке. Очень простая и удобная, писал сам. Есть еще альтернатива - программа CSamp, хотя скорее моя прога - альтернатива этой, в общем решайте сами что юзать)